How to copy lines in awk command? (ksh scripting is preferred)

Question

I have the below index file

 key1|1|1001
 key1|1|2001
 key2|2|3001
 key2|2|4001
 using this index file, I have to update my main file
 key1|1000|2000|3000|4000
 key2|1000|2000|3000|4000

 The expected output should be
 key1|1001|2000|3000|4000
 key1|2001|2000|3000|4000
 key2|1000|3001|3000|4000
 key2|1000|4001|3000|4000

But my below script.awk is not duplicating the keys in the main file, instead it keeps overwriting the value in the respective index. What is the wrong with the script? awk -f script.awk index.txt main.txt

    #!/bin/awk
BEGIN {
    FS = "|"
}
( NR == FNR ) {
    lookup[toupper($1)] = $0
}

( NR > FNR ) {
    key = toupper($1)
    split(lookup[key], replacements, "|")
    for (i = 1; i <= NF; i++)
        col[i] = $i;
    for (i=1; i <= NF; i=i+1){
    j=replacements[i]
    col[j] = replacements[i+1]
    }
    for (i = 1; i <= NF; i++)
        printf "%s|", col[i]
}

jimmij · Accepted Answer · 2014-10-24 06:51:59Z

You were close, just unnecessarily complicated this task. Try awk -f script.awk main.txt index.txt (notice reverse order of files) with the following script:

#!/bin/awk

BEGIN {
    FS = "|"
}
( NR == FNR ) {
    lookup[toupper($1)] = $0
}

( NR > FNR ) {
    key = toupper($1)
    n=split(lookup[key], replacements, "|")
    replacements[$2+1]=$3
    for (i=1; i<n+1; i++)
        printf "%s|", replacements[i]
    printf "\n"
}

The result is

 key1|1001|2000|3000|4000|
 key1|2001|2000|3000|4000|
 key2|1000|3001|3000|4000|
 key2|1000|4001|3000|4000|

Not sure if you want to keep pipes | at the end of the lines, but it is trivial to remove them anyhow.

The main problem with your approach was that array lookup was overridden each time the new line had the same key as previous one. Thus one has to reverse order of files - first read this one which has unique first field to use it as an array index.

And BTW, this is pure awk solution, nothing to do with ksh or any other shell.

Stack Exchange Network

How to copy lines in awk command? (ksh scripting is preferred)

1 Answer 1

You must log in to answer this question.

Hot Network Questions

How to copy lines in awk command? (ksh scripting is preferred)

1 Answer 1

You must log in to answer this question.

Related

Hot Network Questions