Let the script below exemplify my quandary..
#!/bin/zsh
STUFF=( moose-hoof ovary clydsedale )
echo ${MINE=$(printf "MY-%s " $STUFF)}
echo ${MINE_EXP=${STUFF/^/MY-}}
MY-moose-hoof MY-ovary MY-clydsedale
moose-hoof ovary clydsedale
What are the right expansion flags to allow string concatenation on each element of the array?
Use $^array.
It turns the array into a sort of brace expansion of the array. As in when a=(foo bar baz), $^a would be a bit like {foo,bar,baz}.
$ a=(foo bar baz)
$ echo prefix${^a}suffix
prefixfoosuffix prefixbarsuffix prefixbazsuffix
For multiplexing arrays:
$ a=(1 2 3) b=(a b c)
$ echo $^a$^b
1a 1b 1c 2a 2b 2c 3a 3b 3c
Naturally, if the prefix or suffix contain shell special characters (like ; that separates commands or space that separate words, or $"'&*[?~...), they must be quoted:
echo 'p r e f i x '$^a' s u f f i x'
same as for csh's (and bash, ksh, zsh's):
echo 'p r e f i x '{foo,bar,baz}' s u f f i x'
$^a itself must not be quoted, "foo${^a}bar" would expand as one word. One case where you would want $^array to be quoted, the same as for $array is when you want to preserve empty elements. Then, you need to quote the array expansion and use the (@) flag or the "${array[@]}" syntax (reminiscent of the Bourne shell's "$@"):
$ array=(x '')
$ printf '<%s>\n' $array # empties removed
<x>
$ printf '<%s>\n' "$array" # array elts joined with spaces
<x >
$ printf '<%s>\n' "${(@)array}" # empties preserved
<x>
<>
$ printf '<%s>\n' "$array[@]" # empties preserved
<x>
<>
$ printf '<%s>\n' $^array$^array # empty removed
<xx>
<x>
<x>
$ printf '<%s>\n' "$^array$^array" # concatenation of joined arrays
<x x >
$ printf '<%s>\n' "$^array[@]$^array[@]" # multiplexing with empties preserved
<xx>
<x>
<x>
<>
echo "number ${^$(seq 3)} " -> number 1 2 3 or Z=( $(seq 3) ); echo "number ${^Z}" -> number 1 2 3
echo "number "${^$(seq 3)}"" would it work. i have NEVER seen double quotes inside double quotes like that. VERY weird. VERY hard to remember.. but thanks!
${^(seq 3)}, see edit.
while this is a fairly old thread, i wanted to add a recent discovery of mine to do the same thing with parameter expansion replace:
${name/pattern/repl}...
The pattern may begin with a ‘#’, in which case the pattern must match at the start of the string, or ‘%’, in which case it must match at the end of the string, or ‘#%’ in which case the pattern must match the entire string. The repl may be an empty string, in which case the final ‘/’ may also be omitted. To quote the final ‘/’ in other cases it should be preceded by a single backslash; this is not necessary if the ‘/’ occurs inside a substituted parameter. Note also that the ‘#’, ‘%’ and ‘#% are not active if they occur inside a substituted parameter, even at the start.
this allows to match a pattern at the start / end of the string and as there is no constrain to have a pattern only with # or % it can be used for prefixing and suffixing arrays:
$ array=(foo bar baz)
$ echo ${array/#/prefix_}
prefix_foo prefix_bar prefix_baz
$ echo ${array/%/_suffix}
foo_suffix bar_suffix baz_suffix
while certainly not as handy for string as they can be manipulated more easily, it's still doable:
$ string="bar"
$ echo ${string/#/foo_}
foo_bar
$ echo ${string/%/_baz}
bar_baz
