Add a line before a string in a file using awk

$ cat tst.awk
BEGIN {
    RS=""; ORS="\n\n"; FS=OFS="\n"
    skip["[general]"]
    skip["[providertrunk0]"]
    add = "allow = alaw"
    tgt = "nat = no"
}
!($1 in skip) {
    for (i=1; i<NF; i++) {
        if ( ($i != add) && ($(i+1) == tgt) ) {
            $i = $i OFS add
        }
    }
}
{ print }

.

$ awk -f tst.awk file
[general]
disallow = all
allow = ulaw
nat = no

[providertrunk0]
disallow = all
allow = ulaw
;allow = alaw
nat = no

secret =
allow = alaw
nat = no
progressinband = yes

allow = ulaw
allow = alaw
nat = no
progressinband = yes

disallow = all
allow = ulaw
allow = alaw
nat = no
progressinband = yes

Setting RS to null puts awk in paragraph mode (see RS = "" in https://www.gnu.org/software/gawk/manual/gawk.html#Multiple-Line) so your input is split into multi-line records separated by blank lines. Setting ORS="\n\n" ensures you get a blank line between records when output. Setting FS and OFS to "\n" means that the record is split into fields. So then the rest of the code is trivial as you can just compare specific fields (lines) with the values mentioned in your question. skip[] is just the name I made up for any array where I store the first-field (first-line) strings I want to ignore for further processing in that array and then for each record test if the first field/line of the record is in the array and, if so, skip processing it.